final: prev: {
  august-rsps = prev.stdenv.mkDerivation rec {
    pname = "august-rsps";
    version = "0.0.1";

    jar = prev.fetchurl {
      url = "https://cdn.discordapp.com/attachments/1223340813317308580/1291311940165046302/AugustRSPS_Launcher.jar?ex=68cfb375&is=68ce61f5&hm=33c31fbfe089624dc8aced1ddf1e663dc5c6eccec3072e36b458d38bbca2edc8&";
      hash = "sha256-RY191f/LjNaJiobwoSMNm1yWEBSV7dFRfqru/BNNhv4=";
    };

    jogl = prev.fetchurl {
      url = "https://repo.runelite.net/net/runelite/jogl/jogl-all/2.4.0-rc-20200429/jogl-all-2.4.0-rc-20200429-natives-linux-amd64.jar";
      hash = "sha512-OmJIbk5pKtvf1n1I5UHu6iaOKNrPgmaJTPhqC8yMjaRh/Hso1vV/+Eu+zKu7d5UiVggVUzJxqDKatmEnqFrzbg==";
    };
    gluegen = prev.fetchurl {
      url = "https://repo.runelite.net/net/runelite/gluegen/gluegen-rt/2.4.0-rc-20220318/gluegen-rt-2.4.0-rc-20220318-natives-linux-amd64.jar";
      hash = "sha512-kF+RdDzYEhBuZOJ6ZwMhaEVcjYLxiwR8tYAm08FXDML45iP4HBEfmqHOLJpIakK06aQFj99/296vx810eDFX5A==";
    };
    dontUnpack = true;

    nativeBuildInputs = [
      prev.makeWrapper
      prev.unzip
    ];
    installPhase = ''
      mkdir -p $out/share/august-rsps
      mkdir -p $out/natives

      unzip ${jogl}    'natives/*' -d $out
      unzip ${gluegen} 'natives/*' -d $out

      ln -s ${jar} $out/share/august-rsps/AugustRSPS_Launcher.jar

      makeWrapper ${prev.jre}/bin/java $out/bin/august-rsps \
        --chdir "$out" \
        --prefix LD_LIBRARY_PATH : "${prev.xorg.libXxf86vm}/lib" \
        --prefix LD_LIBRARY_PATH : "/run/opengl-driver/lib:/run/opengl-driver-32/lib" \
        --add-flags "-jar $out/share/august-rsps/AugustRSPS_Launcher.jar"
    '';

    meta = with prev.lib; {
      description = "August RSPS Launcher";
      maintainers = with maintainers; [iofq];
      platforms = ["x86_64-linux"];
    };
  };
}